import flash.display.MovieClip;

//stop the current loop
stop();
//set all the arrays we'll be using to store data
var questions = new Array();
var questiontype = new Array();
var answers = new Array();
var images = new Array();
var answerimages = new Array();
var explainations = new Array();
//set the variables that we'll be using to keep track of data to zero
var currentquestion = 0;
var correctamount = 0;
var amountofquestions = 0;
//a loader is created for the XML file
var ul = new URLLoader();
//a variable is created to hold the XML file
var quizXML:XML;
var curLanguage:String;

function init($xmlPath, $curLanguage)
{
	curLanguage = $curLanguage;

	start.addEventListener(MouseEvent.CLICK,function(evt:Event) {
		gotoAndStop('questions');
		
		var wrapper:MovieClip = MovieClip(parent.parent.parent);
		if(wrapper != null) wrapper.trackPlay(curLanguage);
	})
	//a listener is attached and the xml file is loaded
	ul.addEventListener(Event.COMPLETE,dataLoaded);
	ul.load(new URLRequest($xmlPath));	
}
//if it is succesfully loaded..
function dataLoaded(evt:Event) {
	quizXML = new XML(evt.target.data);
	//the amount of questions is gathered
	amountofquestions = quizXML.question.length();
	//is the quiz random?
	//create a random sequence of numbers
	var randomsequence = new Array();
	if (quizXML.@random == 'yes' || quizXML.@random == 'Yes') {
		//if the sequence isnt full yet
		while (randomsequence.length<amountofquestions) {
			//grab a random number
			var randomnumber = Math.floor(Math.random()*amountofquestions);
			//chech if it's not in the sequence yet
			if (!searchArray(randomnumber, randomsequence)) {
				randomsequence.push(randomnumber);
			}
		}
	}
	else {
		for (var i = 0; i<amountofquestions; i++)
			randomsequence.push(i)
	}
	//repeat this loop for each question
	for (i=0; i<amountofquestions; i++) {
		//store the question
		questions.push(quizXML.question[randomsequence[i]].questiontext);
		//store the type of question (multiple choice/true or false/guesstimator)
		questiontype.push(quizXML.question[randomsequence[i]].@type);
		//store the answers according to the different questiontypes
		if (questiontype[i] == 'multiplechoice') {
			//a subarray is created
			answers.push(new Array());
			for (var j=0; j < quizXML.question[randomsequence[i]].answers.answer.length(); j++) {
				answers[i].push(quizXML.question[randomsequence[i]].answers.answer[j])
			};
		} else if (questiontype[i] == 'trueorfalse') {
			//the answer is simply stored as true or false string
			answers.push(quizXML.question[randomsequence[i]].@answer);
		} else if (questiontype[i] == 'guesstimate') {
			//the answer is [0], the lowest is [1] and the highest is [2]
			var bestanswer = parseInt(quizXML.question[randomsequence[i]].@answer);
			var margin = parseInt(quizXML.question[randomsequence[i]].@margin);
			answers.push(new Array(bestanswer, (bestanswer-margin), (bestanswer+margin)));
		}
		//if there is an illustration
		if (quizXML.question[randomsequence[i]].@illustration) {
			//save it in the images array
			images.push(quizXML.question[randomsequence[i]].@illustration);
		} else {
			//otherwise save an empty image
			images.push(undefined);
		}
		if (quizXML.question[randomsequence[i]].@answerillustration) {
			//save it in the images array
			answerimages.push(quizXML.question[randomsequence[i]].@answerillustration);
		} else {
			//otherwise save an empty image
			answerimages.push(undefined);
		}
		//and store the explaination into the explainations array
		explainations.push(quizXML.question[randomsequence[i]].explaination);
	}
};
//this function searches through arrays and sees if they contain a value
function searchArray(needle, haystack):Boolean {
	for (var i=0; i<haystack.length; i++) {
		//each entry is compared to the required value
		if (haystack[i] == needle) {
			//true is returned when found
			return true;
		}
	}
	//otherwise, false is returned
	return false;
}